10. Calculus: Derivatives, Series, Limits, Integration

2016-07-08

$Version

10.1  Derivatives

10.1.1  Common and Partial Derivatives

D[f,x]   					Derive  f  once  w.r.t.  x  
	
D[f, x, y]    				Derive  f  w.r.t. x, then  w.r.t.y

D[f, {x, nx}]				Derive  f   w.r.t.   x    nx   times
D[f, {x, nx} {y, ny}, ...}	Derive  f  w.r.t.x    nx  times,
						then w.r.t.  y    ny   times, etc.

f = Sin[a x]

g = D[f,x]

h = D[f, {x,4} ]

f = Exp[ a x  +  b y  + c z ]

g = D[f, {x,2}, {y,3}, {z,2} ]

Clear[f]
g = D[f,x]

D[Log[x]^2,x]

Legendrepolynome

Legendre polynomials may be generated from the generating function:
	(1/(Sqrt[1-2 x α+(α^2)])) =  (∑_(n=0)^∞)  (α^n) (Subscript[P, n])[x],    [((d^k)/((dα)^k)) (1/(Sqrt[1-2 x α+(α^2)]))]_( α →0)  =  [ (∑_(k=0)^∞) k!  (α^k) (Subscript[P, k])[x]]_( α →0)

legpoly[n_,x_] := D[1/Sqrt[1 - 2 a x + a^2], {a,n}]/n! /.
a -> 0

legpoly[2,x]

f = legpoly[10,x]//Apart

LegendreP[10, x]//Apart

f/. x -> 1

Normierung für x=1 -> P=1

f = LegendreP[3, Cos[th]]

g = Expand[f, Trig -> True]

TrigReduce[g]

10.1.2  Derivatives of Unknown Functions

Clear[f]

D[ f[x]^2,x]

D[ x f[x]^2,x]

D[%,x]

For functions of serveral variables the derivatives are declared in a list attached to the upper right of thename.

Clear[g];
D[g[x,y],x]

D[g[x,y],y]

D[g[x,y],x,y]

D[g[x^2,y^3],x]

D[g[x^2,y^3],y]

D[g[x^2,y^3],{x,2}]

% /. x -> 0

10.1.3	Total Derivatives

Dt[f]        		total differential  df  	

Dt[f,x]			total derivative   df/dx
  	
Dt[f,x,y,...]    		Multiple total derivative  (d/dx)(d/dy)(...) f 

Dt[f, x, Constants -> {c1, c2, ...} ]       			
				Total derivative with   ci = const.
           
  z/: Dt[z,x] = 0	Set  dz/dx = 0

SetAttributes[c, Constant]	define  c  to be a constant in all cases

The operator D[f, x, y, z, ....] denotes a derivative where x, y, z are independent of each other.  
Whereas in Dt[f, x, y, z, ...] all variables which have not been declared constant are asssumed to depend 
on the variable of the actual derivation.

D[x^2 + y^2, x]

Dt[x^2 + y^2, x]

% /. Dt[y,x] -> D[y[x],x]

D[x^2 + y[x]^2, x]

y /: Dt[y,x] = 0

Dt[x^2 + y^2 + z^2, x]

Clear[y]; 
Dt[x^2 + y^2 + z^2, x]

Dt[x^2 + y^2 + z^2, x, Constants->{z}]

SetAttributes[c, Constant]

Dt[a^2 + c x^2, x]

Dt[a^2 + c[x] x^2, x]

Dt[x^2 + c y^2]

% /. Dt[y] -> dy

The total derivative may also be used to change the dependent variable in a differential equation.     For example, in the differential operator    y'' + y' + y the dependent variable y(x) is replaced by     z(x)/v(x)^(1/4).     The resulting  differential operator has no longer a first derivative of the dependent variable (=  normal form of  a second order differential operator):

Clear[x, R, V, f0,f1,f2]

f0 = y = z v^(-1/4)

f1 = Dt[f0,x]

f2 = Dt[f1,x]

ft0 = Dt[v,{x,2}]/4 f0

ft1 = Dt[v,x] /2 f1 //Expand

ft2 =  v f2//Expand

ft0 + ft1 + ft2

(ft0 + ft1 + ft2)/v^(3/4)//Cancel//Apart

So the above differential operator das not contain  Dt[z,x]. This is valid for any function v, 
in particular for  v = x  and v = (x^4) :

% /. v ->   x

%% x^2 /. v -> (x^4)//Expand

10.2  Series Expansions

10.2.1 Taylor and Laurent Series

10.2.1.1 Expanding a Function

Series[expr, {x,x0,nx}]	expands expr around    x = x0   up to  n-th power

Series[expr, {x,x0,nx}, {y,y0,ny}]	Expansion  in  x, y

Normal[series expression]			removes the remainder term       O[...]

f = Series[Exp[x], {x,0,4}]

The remainder term   classifies the expression as a series; this is not the same as a polynomial or other combination of functions. In particular, any function added to the series will be replaced automatically by its series:

g = f + Exp[2 x]

The command Normal[] removes the remainder term; the resulting expression consists of common functions.

Normal[f] + Exp[2 x]

Series[Sin[x], {x,0,4}]

h = Series[Exp[x], {x,1,2}]

Series[Log[1 + x], {x,0,5}]

t = g^2

Below we get a Laurent series:

Series[Exp[x]/x^2, {x,0,4}]

Series[Sin[x]/x^2, {x,0,3}]

Series[Exp[Sqrt[x]], {x,0,2}]

Series[Log[x], {x,0,3}]

Series[Exp[2 x] Log[x], {x,0,2}]

Series[Exp[1/x], {x,0,2}]

(e^(1/x)) has an essential singularity at  x = 0.  So  it is not possible to provide an expansion
around this point. But the function  (e^(1/x)) may be expanded arount x = ∞:

Series[Exp[1/x], {x, Infinity, 3}]

Series[(a + x)^n, {x,0,2}]

Clear[f,g];
Series[ f[x], {x,0,3}]

Functions of several variables may be expanded w.r.t. all variables. The resulting
expression may appear as different depending on the sequence of the expansions.

Clear[x,y, g]
Series[ g[x,y], {x,0,3}, {y,1,2} ]

f = Series[ Exp[a x + b y], {x,0,3}, {y,0,3} ]

g = Series[ Exp[a x + b y],{y,0,3},{x,0,3} ]

f - g //Simplify

f = Series[Exp[x], {x,0,4}]

g = f^2

h = Log[g]

g = 1/(1 - f)

f = Series[Cos[x], {x,0,5}]

g = D[f,x]

h = Integrate[g,x]

f - h

k = 1/f

f = Series[Sin[x], {x,0,5}]

g = f + Sin[x]

g = Normal[f]

g + Sin[x]

Plot[{f,Sin[x]},{x,0,π},Ticks->{{0,(π/2),π},Automatic},ImageSize -> 200 ]

SeriesData::"ssdn" : Attempt to evaluate a series at the number 0.0000641782`. Returning indeterminate.>>
...

The source of the above troubles is the remainder term contained in  f.   g no longer contains this, so everything works smoothly:

ps=Plot[{g,Sin[x]},{x,0,π},Ticks->{{0,(π/2),π},Automatic}];
pa=Plot[g-Sin[x],{x,0,π},Ticks->{{0,(π/2),π},Automatic}];
Show[GraphicsRow[{ps,pa}],ImageSize->350]

Solve[ f == 0,x]

There is no solution since f is no polynomial but an expression with a remainder term.
g no longer contains it, we get the roots of the resulting fifth orer polynomial:

Solve[ g == 0,x]

10.2.1.2 Substituting Series into Series. Inverse Series

Series1[x] /. x -> Series2[x] 	Inserts  Series2  into   Series1. 
InverseSeries[Series]

Series[Sin[x], {x,0,5}]

% /. x -> Series[Sin[x], {x,0,5}]

Series[Sin[Sin[x]], {x,0,5}]

f = Series[Sin[y], {y,0,5}]

g = InverseSeries[f]

k = Series[ArcSin[x], {x,0,5}]

The reciprocal of a series

1/f

g /. y -> f

differs from the series expansion of the inverse function.

f = Series[Cot[x], {x,0,5}]

g = InverseSeries[f]

h = f /. x-> g

f = Series[1 - Cos[x], {x,0,8}]

g = InverseSeries[f]

f /. x -> g

ExpandAll[%]

f = Series[ Cos[x], {x,0,5} ]

g = InverseSeries[f]

f = Series[ Cos[x], {x,Pi/2,5} ]

f = Series[BesselJ[3,x], {x,0,5}]

f = Series[BesselJ[n,x], {x,0,5} ]

f = Series[BesselY[n,x], {x,0,5} ]

g = f /. n -> 3

However, he Bessel function of the second kind, (Subscript[Y, n])(x),  is also well defined for integer order n, e.g. for n = 3:

Series[BesselY[3,x], {x,0,8} ]

10.2.1.3 Residues

Assume z0 as a n-th order pole of a complex function  f(z). In the Laurent series around this singular point

	f(z)  =  ((Subscript[a, -n])/(((z - z0 ))^n)) +  ((Subscript[a, -(n - 1)])/(((z - z0 ))^((n - 1)))) + ... + ((Subscript[a, -1])/(((z - z0 ))^n)) +  P(z - z0)
	
(Subscript[a, -1]) is called the residue. It is very important in Cauchy's residue theorem.

Residue[expr, {x,x0} ]  Residue of expr at x  = x0

Residue[1/x, {x,0} ]

Residue[1/x^2, {x,0} ]

Residue[Exp[I 2x]/x^4, {x,0}]

Residue[ Cos[x]/x^3 - Sin[x]^2/x^3, {x,0} ]

Residue[Gamma[x], {x,-2} ]

Limit[ (x + 2) Gamma[x], x -> -2 ]

Limit[ (x + 3) Gamma[x], x -> -3 ]

Residue[BesselJ[2,x]/x^3, {x,0}]

LegendreP[2,x]

Residue[LegendreP[2,x]/x^3, {x,0} ]

Residue[ LegendreP[n,x]/x^(n+1), {x,0} , Assumptions -> Element[n,Integers]]

LegendreQ[2,x]

f = Series[ LegendreQ[2,x], {x,Infinity,5} ]

Residue[ LegendreQ[2,x], {x,Infinity} ]

Residue[ LegendreQ[2,x] x^2, {x,Infinity} ]

Residue[ BesselY[1,x], {x,0}]

Limit[ BesselY[1,x] x, x -> 0]

10.3  Limits

10.3.1 Common Limits

Limit[expr,  var  -> value]

Limit[ Sin[2x]/x,  x -> 0]

Limit[ (Sin[2x]/x)^2,  x -> 0]

Limit[ Sin[2x]^2/x,  x -> 0]

Limit[ Sin[2x]/x^2,  x -> 0]

Limit[ 1/Sin[x] - Coth[x],  x -> 0]

Limit[ x/Sin[Pi - x], x -> 0 ]

Limit[ 1/x,  x -> Infinity]

Clear[g];
g[x_] = Sqrt[x^2 - 4 x] - x;

Limit[ g[x], x -> Infinity ]

f = (q^a - q^-a)/(q - q^-1)

Limit[f, q -> 1]

theta[x_] = Which[x > 0, 1, x == 0, 1/2, x < 0, 0 ]

Limit[theta[x], x -> 0]

Sign[0.1]

Sign[0]

Sign[-1]

Limit[Sign[x],  x -> 0]

Limit[Sign[x], x -> 0.1]

10.3.2 Directional Limits

Limit[expr, x -> x0, Direction ->  1]   Limit from below 

Limit[expr, x -> x0, Direction -> -1]   Limit from above

Clear[f];
f[x_] = 1/x

Limit[f[x], x -> 0, Direction -> -1 ]

Limit[f[x], x -> 0, Direction ->  1 ]

Limit[Sign[x], x -> 0, Direction -> -1 ]

Limit[Sign[x], x -> 0, Direction ->  1 ]

theta[x_] = Which[x > 0, 1, x == 0, 1/2, x < 0, 0 ]

Limit[theta[x], x -> 0, Direction -> 1]

Limit[ Exp[Tan[x]/Log[Cos[x]]], x -> π/2, Direction -> -1]

Limit[ Exp[Tan[x]/Log[Cos[x]]], x -> π/2, Direction -> 1]

Clear[a, r, it]
it = Integrate[r^2 Exp[-a r^2 ], {r, 0, r}]

Limit[it,r -> Infinity]

The limit is ruther simple: The first term becomes zero. 
Erf[∞] = 1;  so the second term gives  (Sqrt[π])/(4 (a^(3/2))).

a = 3;

it[[1]] /. r -> 5//N

Erf[(Sqrt[a])Infinity]

it[[2]] /. r -> 5//N

0.08527722566220737`

Sqrt[π]/4 / (a^(3/2))//N

10.4   Integration

10.4.1  Analytic Integration

In same cases the result of an indefinite or definite analytic integration or an error message may be wrong. So checks or critical appraisals are strongly recommended. A kind of check may be numerical integration of the same integral.
If the results of these two types of integration differ it is not always clear which result is wrong !

10.4.1.0	    Short commands for inputing integrals

Use Esc int Esc to enter ∫ and Esc dd Esc to enter d:

∫ x \[DifferentialD]x

Use the menue "Palettes", in the appearing menue "Other". Click the integral sign. 
Color this by pressing simultaneously Upper case and the left shift arrow. 
Then click at the symbol (Subscript[■, □]^□) in the palette. Insert lower and upper limits of the integral into the empty boxes.

(∫_a^b)  x \[DifferentialD]x

10.4.1.1  Indefinite Integration

Integrate[f, x]			    		∫ dx   f

Integrate[f, x, y ]			    		∫  dx   ∫  dy  f		=

Integrate[Integrate[f,y],x]		∫ dx   ∫  dy  f

g = Integrate[Sqrt[x], x]

uous function

D[g,x]

f = ( (x - 1)^2 (x^2 + 1)^2 )^-1

g = Integrate[f,x]

h = D[g,x]

Together[h]

Table[h[[k]],{k,Length[h]}]

Clear[x,f]

f = (x^3 - 7)^-1

Integrate[f, x]

f = (x^3 + x^2 - 7)^-1

Integrate[f, x]

ni = N[%]

ComplexExpand[ni]

ni[[2]]

so = Solve[1/f == 0,x]

g = Integrate[x^3 Log[x], x]

D[g,x]

g = Integrate[x^2/Sqrt[x^2 - 9], x]

D[g,x]

Together[%]

Clear[a,b,f,g,x]
f = Sqrt[(a^2 - x^2)(b^2 - x^2)]/x

The radicand of the above function is a fourth order polynomial in  x.  In general, integrals over square roots containing third or fourth order polnomials cannot be expressed as combinations of elmentary functions. One is forced to introduce new transcendental functions, called elliptic integrals and elliptic functions.  
But the integral over the function  f  above can be expressed by elementary functions, so it is called a pseudoelliptic integral:

g = Integrate[f,x]

FullSimplify[g]

D[g,x];

FullSimplify[%]

So the integral is checked by differention. In the literature one finds a simpler expression for this integral:

go=(1/2)   (Sqrt[(a^2)-(x^2)]) (Sqrt[(b^2)-(x^2)])+(1/4) ((a^2)+(b^2)) Log[(((Sqrt[(a^2)-(x^2)])+(Sqrt[(b^2)-(x^2)]))/(-(Sqrt[(a^2)-(x^2)])+(Sqrt[(b^2)-(x^2)])))]- (1/2) a b Log[((b (Sqrt[(a^2)-(x^2)])+a (Sqrt[(b^2)-(x^2)]))/(-b (Sqrt[(a^2)-(x^2)])+a (Sqrt[(b^2)-(x^2)])))] ;

dg = D[go,x]

FullSimplify[dg] //Timing

On differentiating integrals over trigonometric functions, the resulting expression may differ from the original integrand. Nevertheless a check is possible:

f = Sin[3 x] Cos[x]^2

g = Integrate[f,x]

h = D[g,x]

k = h - f

Simplify[k]

On integrating functions of several variables over several of these may lead to different expressions depending on the order of the integration. This is not incorrect, since the derivative of the difference is zero.

Clear[x, y, z, r]
r = Sqrt[x^2 + y^2 + z^2]

gxy = Integrate[x^2/r, x, y]

gyx = Integrate[x^2/r, y, x]

dg = gxy - gyx

Simplify[dg]

D[dg,x,y] //Together

Integration by hand gives:

g = x y r/6 + z^3 ArcTan[x y/(z r)]/3 - 
  	(y^3 + 3 y z^2) Log[x + r]/6 + x^3 Log[y + r]/3

f = D[g,x,y]//Together

gxy = Integrate[x^2/r^2, x, y]

In fact, a more detailed and lengthy analysis not given here shows that the above integral cannot be expressed by elementary functions.

rr = Sqrt[x^2 + y^2]

k = Integrate[rr^-3, x, y]

D[k, x, y] //Together

f = Sqrt[1 + x^6]/x

Integrate[f,x]

Clear[a,x];  
f = ArcSinh[a/x];
g = Integrate[f,x]//ExpandAll//PowerExpand

h = D[g,x] //FullSimplify

One may perform the integration by hand by partial integration. In this way one gets:

 ∫  Arsh(a/x) dx 	=  x  Arsh(a/x)        +        ∫ dx  a/x  1 / sqrt[1 + (a/x)^2]
              		=  x  Arsh(a/x)        +     a  ∫ dx / sqrt(a^2 + x^2)
              		=  x  Arsh(a/x)        +       a  Arsh(x/a)

g1 = x ArcSinh[a/x] + a ArcSinh[x/a];
h1 = D[g1,x]

Simplify[h1,(x>=0&& a>= 0)]

Indefinite integrals over discontinuous functions, as e.g. Abs[x], Sign[x] are not done. 
A workaround is to define them via the UnitStep[x] function:

Integrate[Abs[x],x]

Integrate[2x UnitStep[x]-x,x]

Show[GraphicsRow[{Plot[Abs[x],{x,-1,1},AxesLabel->{"x","Abs[x]"}],Plot[2 x UnitStep[x]-x,{x,-1,1},AxesLabel->{"x","2 x UnitStep[x] - x"}]}],ImageSize->400]

NIntegrate[Abs[x],{x,-1,2}]

Integrate[2x UnitStep[x]-x,{x,-1,2}]

10.4.1.2    Definite Integrals

Limits of integration may be inserted by substitutions after the indefinite integration has been performed.

g = Integrate[Sin[x], x]

gt = g /. x -> Pi/2   -   g /. x -> 0

gt = (g /. x -> Pi/2 )  -  ( g /. x -> 0)

Integration limits can be given in the command  Integrate[]

Integrate[f, {x,x0,x1}]					(∫_x0^x1)f(x)dx

 Integrate[f, {x,x0,x1}, {y,y0,y1}]			(∫_x0^x1) (∫_y0^y1) f[x,y]dydx

Integrate[ Sin[x], {x,0,π/2} ]

Integrate[ Sin[.1 x], {x,0,π/2} ]

f = x^3 y^2 z

Integrate[f, {x,a,b}, {y,c,d}, {z,e,m}]

Integrate[Sin[x]/x, {x,0,b} ]

Integrate[((x - 1) Log[x]^(-1) - x)/Log[x],{x,0,1}]

Integrate[1/Log[x]^2 - x/(1 - x)^2, {x, 0, 1}]

N[%] - NIntegrate[1/Log[x]^2 - x/(1 - x)^2, {x, 0, 1}]

Volume of an octant of a homogeneous tri-axial ellipsoid.
Octant  of an ellipsoid:
			  	((x^2)/(a^2))+((y^2)/(b^2))+((z^2)/(c^2))= 1
    
    			0  ≤  x  ≤ a,  0  ≤  y  ≤  b,  0  ≤ z ≤ c.
Earlier  versions of Mathematica could calculate the volume of triaxial  ellipsoid rather easily.
Present versions need some assistance by the user.

vz= Integrate[1, 
	{z,0, c Sqrt[1 - (x/a)^2 - (y/b)^2] } ]

vy = Integrate[vz, {y,0,b Sqrt[1 - (x/a)^2]}, Assumptions-> a > 0 && b > 0  && c > 0 &&  a >  x > 0   ]

v = Integrate[%, {x,0,a}]

Another workaround is to make the usual trigonometric  substitution for the variable  y:

sy =  y -> b (1-((x^2)/(a^2)))^(1/2) Sin[ϕ] ;

vvy = vz /. sy

dy = D[y /. sy,ϕ]

vy = Integrate[vvy dy,{ϕ,0,π/2}]

Integrate[vy,{x,0,a}]

10.4.1.3  Infinite Integrals

Integrate[ 1/x^2  , {x,2,Infinity} ]

Integrate[ 1/x , {x,2,Infinity} ]

Integrate::"idiv" : Integral of  (1/x) does not converge on  [2,∞]. >>

Integrate[Sin[x]/x, {x,0,Infinity} ]

Integrate[(Sin[x]/x)^2, {x,0,Infinity} ]

Integrate[Sin[x]^3/x , {x,0,Infinity}  ]

Integrate[Sin[x]/x^2 , {x,0,Infinity} ]

Clear[x,b,f]
f[x_,b_]=(((x^2) b (E^(b x)))/((((E^(b x))+1))^2)) ;

Integrate[f[x,b],{x,0,∞}]

Simplify[%, b > 0]

Integrate[f[x,b],{x,0,∞},Assumptions->{b>0}]

Integrate[f[x,b],{x,0,∞},Assumptions->{Re[b] >0}]

Integrate[1/2+1/2 Erf[z],{z,-Infinity,0}]

Erf[z] is the error function  ( 2/(Sqrt[π]) ) (∫_0^z)  (e^(- (x^2))) dx  .

10.4.1.3.1 Workarounds, where Mathematica does not succed without assistance

ic = (∫_0^∞)((Cos[a x]  Sin[b x] Sinh[(-c+d) x])/(x Sinh[d x]))\[DifferentialD]x

The algorithms of Mathematica do not succeed. So a simpler intgral is done at first.
The product of trigonometric functions is decomposed:

Clear[a,b,x,fx]
fx = Cos[a x ]Sin[b x]

fxd = TrigReduce[fx]//Expand

α1 = fxd[[2,2,1]]/x//Cancel

α2 = fxd[[1,2,1]]/x//Cancel

A simpler integrand is used at the start. Later on that of  ic  is obtained by integrating both sides w.r.t.  α  and identifying some other parameters.

fi =   Cos[x α ] Sinh[β x]/Sinh[d x]

in =  Integrate[fi,{x,0,Infinity} , Assumptions -> d >β  > 0 && Element[α,Reals]]

ia = Integrate[fi,{α,0,α}]/. {β -> d - c}

iaf = 1/2 (ia /. α -> α1) -  1/2 (ia /. α -> α2)//Together//Simplify

So this is the integrand of the wanted integral  ic. The same operations as above must be applied to in:

ir = Integrate[in,{α,0,α}, Assumptions ->   α > 0 && β > 0 && d > 0]

irr = ir /. {β -> d - c}

irf = 1/2 (irr /. α -> α1) -  1/2 (irr /. α -> α2)//Together//Simplify

ExpToTrig[irf]

irs = FullSimplify[%, Sin[((c π)/d)] > 0]

su = {a -> .37, b -> 1.23, c -> .79, d -> 3.21};

Sin[c π/d] /. su

NIntegrate[((Cos[a x]  Sin[b x] Sinh[(-c+d) x])/(x Sinh[d x])) /. su,{x,0,Infinity}]

irf /. su

irs /. su

10.4.1.4 Complex Integration

For integration in the complex plane the path of integration may be given as a sequence of line elements:

Integrate[1/z,{z,-1,I,1/2}]

N[%]

NIntegrate[1/z,{z,-1,I,1/2}]//Chop

Integrate[1/z,{z,-1,-I,1/2}]

N[%]

NIntegrate[1/z,{z,-1,-I,1/2}]

Integrate[1/z,{z,-1,I,1}]

N[%]

NIntegrate[1/z,{z,-1,I,1}]//Chop

Numeric and analytic integration give the same result.

NIntegrate[1/z,{z,-1,I,2}]

10.4.1.5  Integrals  Leading to Multivalued Functions

Integrals leading to multivalued functions as, for example, logarithms or powers with fractional exponents require special care.  Version 5 and newer versions are better prepared as earlier versions of Mathemtica to deal with that problem.   So the results below are correct.

ia = Integrate[1/z,{z,-1,-I,1,I,-1}]

N[%]//Chop

in = NIntegrate[1/z,{z,-1,-I,1,I,-1}]//Chop

10.4.1.6 Options for Integrate[]

??Integrate

Integrate[Sin[a x]/x, {x,0,Infinity}]

Integrate[Sin[a x]/x, {x,0,Infinity}, Assumptions -> {a > 0}]

??GenerateConditions

Integrate[Exp[-a x^2],{x,0,Infinity}]

Integrate[Exp[-a x^2],{x,0,Infinity},GenerateConditions->False]

Integrate[Sin[a x]/x, {x,0,Infinity}, GenerateConditions -> False]

This is correct for real a, only.  But the flow of the calculation is not interrupted by an  If[].

??Assumptions

Integrate[E^(- a x^2),{x,0,Infinity}]

Integrate[E^(- a x^2),{x,0,Infinity}, Assumptions -> {a > 0}]

Integrate[Sin[t*u-x]*Exp[-a*u^2],{u,-Infinity,Infinity}]

Integrate[Sin[t*u-x]*Exp[-a*u^2],{u,-Infinity,Infinity},Assumptions->{Element[t,Reals], a > 0}]

Element[x,dom]      declares  x  as element  of  dom

Domains are:

Algebraics			algebraic numbers
Booleans			True or  False
Complexes			complex numbers
Integers			integers
Primes			prime numbers
Rationals			rational numbers
Reals				real numbers

10.4.1.7  	Cauchy principal value (= Cauchyscher Hauptwert)

Integrate[Cos[x]/x, {x,-1,2}]

The integrand above has a first order pole at  x = 0. The corresponding Riemann integral does not exist. For such integrals another definition of the integral may be used called the Cauchy principal value. This is defined for integrands,  which contain a first order pole so that the Riemann integral no longer exists. The integrands discussed here have such a pole at  t = 0. So the Cauchy principal value (PV) is defined as the following limit  (a <  0, b > 0):

PV  (∫_a^b) f(t)/t dt  :=  

				limϵ->0 [(∫_a^(-ϵ))  f(t)/t dt  + (∫_ϵ^b) f(t)/t  dt ].

If the singular point is  at  t = (Subscript[t, 0]) then  t  must be replaced by  t - (Subscript[t, 0])  and the integration limits must
be changed according to   - ε  →  (Subscript[t, 0]) - ϵ,    ε  →  (Subscript[t, 0]) + ϵ   respectively.

The integral as defined above is not a Rieman integral, so it is denoted as PV  (=  principal value). 
The contributions of the two singular branches cancel for the particular limit defined. This cannot 
occur, if the particular form of the limit is not observed. For example, a limit

			limϵ->0 [(∫_a^(-ϵ))  f(t)/t dt  + (∫_(ϵ^2)^b) f(t)/t  dt ]

would not exist. Whereas this is a prerequisite for a Rieman integral, where an arbitrary decomposition of the interval of integration must be possible,  i.e. the widths of the stripes approximating the integral  are arbitrary.

An equivalent method to compute the Cauchy principle value uses complex integration. On gets finite values for the integral by choosing an integration path in the complex plane. The principal value is obtained by taking the arithmetic mean of two such complex integrals. The first (second) one uses a path (Subscript[C, U ])((Subscript[C, L]))  passing above (below) the real singular point. Otherwise these paths  are quite arbitrary except there must not be any other  singularity between the original real path and (Subscript[C, U ]) and (Subscript[C, L]).In most cases the paths  (Subscript[C, U ]) and (Subscript[C, L])   may consist of  straight lines starting at a, b respectively and meeting at a complex number located roughly above, below the  singular point respectively.

PV  (∫_a^b) f(t)/t dt  :=   (1/2) [(∫_(a,(Subscript[C, U]))^b)  f(t)/t dt  + (∫_(a, (Subscript[C, L]))^b) f(t)/t  dt ]

??PrincipalValue

Principal Value = Cauchyscher Hauptwert

Integrate[1/x, {x,-1,2}, PrincipalValue -> True]

or by complex integration

iu = Integrate[1/x, {x,-1,I,2}]
il = Integrate[1/x, {x,-1,-I,2}]
(iu + il)/2

Integrate[Cos[x]/x, {x,-1,2}, PrincipalValue -> True]

N[%]//Chop

Clear[t]

Integrate[Sin[t]/t^2, {t,-1,2}, PrincipalValue -> True]

N[%]//Chop

Clear[x,x0,x1,xp]
Integrate[1/(x - xp),{x,x0,x1}, Assumptions  -> (0 < xp < x0 < x1)  ]

Integrate[1/(x - xp),{x,x0,x1}, Assumptions  -> (0 < x0 < x1 < xp)  ]

Integrate[1/(x - xp),{x,x0,x1}, Assumptions  -> (0 <x0 < xp < x1)  ]

Integrate[(1/(x-xp)),{x,x0,x1},Assumptions->0<x0<xp<x1, PrincipalValue -> True]

The corresponding numeric integrations are done in  § 10.4.2.3 .

10.4.2  Numeric Integration

NIntegrate[f, {x,x0,x1}]				(∫_x0^x1)f(x)dx

 NIntegrate[f, {x,x0,x1}, {y,y0,y1}]		(∫_x0^x1) (∫_y0^y1) f[x,y]dydx

NIntegrate[ Sin[x], {x,0,π/2} ]

NIntegrate[ Sin[20 x], {x,0,π/2} ]

Integrate[ Sin[20 x], {x,0,π/2} ]

NIntegrate[Sin[x]/x, {x,0,Infinity} ]

Pi/2 //N

NIntegrate[1/Sqrt[x],{x,0,1}]

Integrate[1/Sqrt[x],{x,0,1}]

NIntegrate[1/Sqrt[Abs[x]],{x,-1,2}]

Singular points of integrands (here  x = 0) may be indicated in the list:

NIntegrate[1/Sqrt[Abs[x]],{x,-1,0,2}]

Results of integrations should always be checked. For example, by  a  numerical integration.

Clear[a];  f = ArcSinh[a/x]; fn = f /. a -> 1.37 ;
g = Integrate[f,x]

gn = NIntegrate[fn, {x,1,2}]

gc = (g /. {a -> 1.37, x -> 2}) - (g /. {a -> 1.37, x -> 1})

Checks of integrations over two or more variables require some care. Compare the formulae below, which
shows that 4 terms of the antiderivative (G.: Stammfunktion) are needed.

F(x) := ∫  f(x) dx :                   ⟹          (∫_x0^x1)f(x)dx  =    F(x1)  -  F(x0)

F(x,y)  :=  ∫∫  f(x,y)  dy   dx           ⟹
(∫_x0^x1)(∫_y0^y1)  f(x,y)  dy   dx    ≠    F(x1,y1)  -  F(x0,y0)     
		                                 =   F(x1,y1)  -  F(x0,y1)   -   F(x1,y0)  +  F(x0,y0)

This is shown for the following example, the integral over the function  f  with antiderivative g.

r = Sqrt[x^2 + y^2 + z^2];

g = x y r/6 + z^3 ArcTan[x y/(r z)]/3 + x^3 Log[y + r]/3 -
	(y^3 + 3 y z^2) Log[x + r]/6

f = Simplify[Together[Simplify[D[g,x,y]]]]

fn = f /. z -> 3.31

nn = NIntegrate[fn, {x,.2,.9}, {y,.1,.7}]

gn = g /. z -> 3.31;
g11 = gn /. {x -> .9, y -> .7}//N ;
g01 = gn /. {x -> .2, y -> .7}//N ;
g10 = gn /. {x -> .9, y -> .1}//N ;
g00 = gn /. {x -> .2, y -> .1}//N ;
dg = g11 - g01 - g10 + g00

10.4.3 Options for NIntegrate[]

??NIntegrate

NIntegrate[1/x, {x, 1, 2}, WorkingPrecision->40]

N[ Log[2], 40 ]

10.4.3.1  Numerical integration with high precision

WorkingPrecision, PrecisionGoal and AccuracyGoal

WorkingPrecision   specifies the number of digits to use for the internal computation. 
The accuracy of the results is influenced by PrecisionGoal and AccuracyGoal. 
The default setting PrecisionGoal -> Automatic, attemps to get results with a 
precision equal to WorkingPrecision = 10 digits. 
In general, NIntegrate[] continues until it achieves either of the goals 
specified by PrecisionGoal or AccuracyGoal.

Clear[x]
g[x_] = x^20 * Exp[x]

Integrate[g[x], {x,0,1}]//Expand

SetAccuracy[ %[[1]],100]
SetAccuracy[ %%[[2]],125]

inta =SetAccuracy[ %+%%,100]

inta  is the result of an analytic integration. The numerical evaluation entails the loss of about
18 decimal places. Nevertheless it gives 100 reliable decimal figures.

nint =SetAccuracy[ NIntegrate[g[x], {x,0,1}],100]

inta - nint

The numerical integration above gives only an accuracy of 18 decimal places. But that 
below with the two options produces a result with 100 correct decimal figures:

nint100 = NIntegrate[g[x],{x,0,1},AccuracyGoal->100,WorkingPrecision->200]

inta - nint100

MinRecursion  and  MaxRecursion

When  NIntegrate[]  tries to do a numerical integral, it samples the integrand at a sequence of points. It it finds that the integrand changes rapidly in a particular region, then it recursively takes more sample points in that region. The parameters MinRecursion  and  MaxRecursion  specify the minimum and maximum number of levels of recursive subdivions to use. Increasing MinRecursion  garantees that  NIntegrate[]  will use a larger number of sample points.  MaxRecursion  limits the number of sample points. 
SingularityDepth  specifies how many levesl of recursive subdivions  NIntegrate[]  will try.

Plot[Exp[-(x^2)],{x,-5,5},PlotRange->All]

N[NIntegrate[Exp[- x^2], {x,-1000,1000}],22]

in = SetPrecision[NIntegrate[N[Exp[- x^2],44], {x,-1000,1000},
                           MinRecursion -> 3, MaxRecursion -> 10],44]

SetPrecision[NIntegrate[Exp[- x^2], {x,-1000,1000}],44]

% - %%

Integrate[Exp[-x^2],{x,-1000,1000}]

ia = N[%,44]

N[(Sqrt[π]) Erf[Infinity],44]

in - ia

In order to check the accuracy of the analytic result, an asymptotic formula for large a  is obtained by partial integrations: 

(∫_0^a)(e^(-(x^2)))dx  =  (∫_0^∞)(e^(-(x^2)))dx  -  (∫_a^∞)(e^(-(x^2)))dx   =  (Sqrt[π])/2  -  (∫_a^∞) (- 2 x)(e^(-(x^2))) (((-1)/(2x)))   dx 
								u'	      v
	       = (Sqrt[π ]) /2  - [((e^(-(x^2)))/(2x))]_a^∞    +   (∫_a^∞) (e^(-(x^2))) ((1/(2(x^2))))   dx  =  (Sqrt[π ]) /2 - 0  +  ((e^(-(a^2)))/(2a))  + ...
	       
This procedure could be continued, but this is not necessary if a is sufficiently large as it is here:

N[(Sqrt[π]),44]

((E^(-(a^2)))/(2a)) /. a -> 100//N

10.4.3.2 Integration of a discontinuous function

Clear[f,x]
f[x_]:= Which[ x<0, 0, x<1, 1, x>=2, 2 -x, x>=1, x];

Plot[f[x],{x,-1,4},PlotStyle->Thickness[0.01`]]

NIntegrate[f[x],{x,-1,4}]

10.4.3.3  Numeric Principal  Value Integrals

The definition of the principal value given in 10.4.1.7 and the methods to evaluate it apply also here.

Evaluation by the option   Method -> ”PrincipalValue”

Integrate[Sin[x]/x^2,{x,-1,2}]

Integrate[Sin[x]/x^2,{x,-1,2},PrincipalValue -> True ]

N[%]//Chop

NIntegrate[Sin[x]/x^2,{x,-1,0,1,2},Method->"PrincipalValue"]

Integrate[(1/(x-(x^2))),{x,-1,2},PrincipalValue -> True ]

N[%]

NIntegrate[(1/(x-(x^2))),{x,-1,0,1,2},Method->"PrincipalValue"]

Note: The very last integral above has two first oder poles, one at  x = 0, the other at  x = 1 . 
It is essential  that in the argument list of  NIntegrate[]   the position(s) of the first order pole(s) is (are) given accurately. Otherwise the command will yield a wrong result. So the position of the pole must be found beforehand to high precision !

n[x_] = 1+(x^2) ;  
d[x_] = x^5 + x^2 + x + 0.5;

(∫_(-1)^1) n[x]/d[x]  \[DifferentialD]x

Plot[n[x]/d[x],{x,-2,1},AxesLabel -> {"x","n(x)/d(x)"}]

so = Solve[d[x]==0]

xp = x/. so[[1]]

Integrate[n[x]/d[x] ,{x,-1,1},PrincipalValue -> True ]//Chop

That the above analytical principal value integration works is an exception. 
Exercise 10.10 is an example to the contrary.

inPV =NIntegrate[n[x]/d[x] ,{x,-1,xp,1},Method->"PrincipalValue"]

NIntegrate[n[x]/d[x] ,{x,-1,-0.78,1},Method->"PrincipalValue"]

An inaccurate value for the pole position leads to a wrong result !

Evaluation by complex integration

For this method no accurate value of the pole position is needed.  But the positions of all poles
must be known. The integration paths must have the same starting and end point as the real
original path;  in addition, the resulting closed curve CU + CL must not include any other singularity than the poles on the original path.

plro = ListPlot[{Re[x],Im[x]}/.so];

CU = {{-1,0},{0,0.5},{1,0}};
CL = {{-1,0},{0,-0.5},{1,0}};
plpa = ListLinePlot[{CU,CL}];

Show[plro,plpa, PlotRange -> All, Epilog ->{Text[Subscript["C","L"],{0.2,-0.5}],Text[Subscript["C","U"],{0.2,0.5}]}]

iU = NIntegrate[n[x]/d[x] ,{x,-1,0.5 I,1}]

iL = NIntegrate[n[x]/d[x] ,{x,-1,-0.5 I,1}]

ih =(iU + iL)/2 //Chop

ih - inPV

10.5 Integral Transforms

10.5.1 Laplace Transform

The Laplace Transform of a function f(t)  is defined as  

				F(s) :=   (∫_0^∞)f(t)(e^(-st))dt  := ℒ(f(t))				(1)

LaplaceTransform[expr, t, s]	 gives the Laplace transform of expr

Laplace Transform of a constant c: ℒ(c) =

LaplaceTransform[c, t, s]

LaplaceTransform[(t^n), t, s]

LaplaceTransform[Sin[ω t],t,s]

LaplaceTransform[Cos[ω t],t,s]

LaplaceTransform[t Sin[ω t],t,s]

LaplaceTransform[t Cos[ω t],t,s]

The Heaviside unit step function is a discontinuous function.

ft1=If[t≤a,0,1];
sua=a->1;
Plot[ft1/.sua,{t,0,4},AspectRatio->Automatic,AxesLabel->{"t","f(t)"},Ticks->{{0,{a,"a"}}/.sua,{0,1}},PlotStyle->Thick ]

LaplaceTransform[ft1,t,s]

Integrate[Exp[- s t],{t,a,Infinity}]

A pulse lasting from a to b is shown in the following drawing:

Integrate[Exp[- s t],{t,a,b}]

LaplaceTransform[BesselJ[0,a t],t,s]

LaplaceTransform[BesselJ[n,a t],t,s]

% /. n -> 3 //Simplify

Apart[%]

10.5.1.1	  Transformation of Differential Equations

Deriving  the defining  integral   F(s)=(∫_0^∞)f(t)(e^(-s  t))dt, w.r.t.   t  gives :

		ℒ(f'(t))  =  s F(s) -  f(+0),
			
			ℒ(f"(t))  = (s^2) F(s) - s f(+0) -  f'(+0), ...

Applying  the Laplace  transform  changes  the following  linear  differential  equation  with given  c1, c2 and  f(t):

                             (Overscript[x, ..])(t) +  c1 (OverDot[x])(t) +  c2  x(t)  =  f(t)

 into a linear  algebraic   equation: 

[(s^2) X(s) - s x(+0) -  x'(+0)]  +  c1 [ s X(s) -  f(+0)]  +  C0  =    F(s).

This may  be  solved  for the unknown  amplitude    X(s)  and  x(t)  is found   by the inverse  Laplace  transform .

10.5.1.2  The Inverse  Laplace Transform

The Inverse Laplace Transform is:    (ℒ^(-1))(F(s))   :=  (1/(2πi))(∫_(c-i∞)^(c+i∞))F(s)(e^(st))ds  
where  c  is an arbitrary positive  constant chosen such that the contour 
 of integration  lies to the right of all  singularities  inF(s).

InverseLaplaceTransform[expr, s, t]  gives the inverse Laplace transform of expr

InverseLaplaceTransform[(s/((s^2)+(ω^2))), s, t]

InverseLaplaceTransform[c/s, s, t]

InverseLaplaceTransform[((E^(-a s))/s), s, t]

InverseLaplaceTransform[c, s, t]

10.5.1.3  A Voltage Jump applied to a  Series Circuit

A series circuit consists of a condensor of capacity C (charge q = ∫ i dt  = C V) and a coil having an  Ohmic resistance R (V = R i ) and an inductivity L (V = L di/dt.). A Voltage step  V(t) = V0 θ(t) is applied to this circuit. The current is represented as a Laplace transform F(s) = ℒ(i(t)).

	 ∫ i dt /C  +  R i + L di/dt  =  V(t),     i/C  +  R di/dt  +  L (d^2)i/(dt^2) =  V0 dθ/dt = V0 δ(t);
	 
					 F / C + R s F + L (s^2) F == V0 .

fi = V0/(s R + s^2 L + C)

ti =InverseLaplaceTransform[fi, s, t]

svd = {V0 -> 10,R ->  22, L ->  110, C ->  1};

(ti /. svd //N )/. 2.718281828459045` -> E

Plot[Evaluate[ti/.svd],{t,0,57},PlotRange->All,AxesLabel->{"t","I(t)"}]

svs = {V0 -> 10,R ->  22, L ->  110, C ->  19};

(ti /. svs //N//Expand//Chop )/. 2.718281828459045` -> E

Plot[Evaluate[ti/.svs],{t,0,57},PlotRange->All,AxesLabel->{"t","I(t)"}]

10.5.2  Fourier Transform

FourierTransform[f(t),t, ω]                                 F(ω) =  (1/(Sqrt[2π]))(∫_(-∞)^∞)f(t) (e^(iωt))dt 

InverseFourierTransform[F(ω),t, ω]              f(t) = (1/(Sqrt[2π]))(∫_(-∞)^∞)F(ω) (e^(-iωt))dω

FourierCosTransform[f(t),t, ω]                              F(ω) =  (Sqrt[(2/π)])(∫_0^∞)f(t) cos(ωt)dt 

InverseFourierCosTransform[F(ω), ω,t]       f(t) =  (Sqrt[(2/π)])(∫_0^∞)F(ω) cos(ωt)dω

FourierSinTransform[f(t),t, ω]                              F(ω) =  (Sqrt[(2/π)])(∫_0^∞)f(t) sin(ωt)dt 

InverseFourierSinTransform[F(ω), ω,t]       f(t) =  (Sqrt[(2/π)])(∫_0^∞)F(ω) sin(ωt)dω

ft = 1/(t^2 + a^2);
fw = FourierTransform[ft,t,ω]

PowerExpand[%]

fm =  1/(Sqrt[2π]) Integrate[ft Exp[I ω t],{t,-Infinity,Infinity}, Assumptions -> {a > 0 && Element[ω, Reals]}]

FourierCosTransform[ft,t,ω]

PowerExpand[%]

(Sqrt[2/π])Integrate[ft Cos[ω t],{t,0,Infinity}, Assumptions -> {a > 0 && ω > 0}]

fst = ( UnitStep[t] + UnitStep[a - t] - 1)

sa = {a -> 1};

Plot[fst/.sa,{t,-1,2},PlotRange->{0,1.1`},PlotStyle->Thickness[0.009`],Epilog->Text["0",{0,-0.065`}],ImageSize -> 250,PlotLabel->"f(t) = -1+UnitStep[1-t]+UnitStep[t]\n",AxesLabel->{"t","f(t)"}]

fw = FourierTransform[ft,t,ω]

Simplify[fw , a > 0]

fm =  1/(Sqrt[2π]) Integrate[fst Exp[I ω t],{t,-Infinity,Infinity}, Assumptions -> {a > 0 && Element[ω, Reals]}]

fw = InverseFourierTransform[fm,ω,t]

Plot[fw/.sa,{t,-1,2},PlotRange->{0,1.1},PlotStyle->Thick,ImageSize -> 250,PlotLabel->"f(t) = [Sign(a - t) + Sign(t)]/2\n",AxesLabel->{"t","f(t)"}]

But this integral may be evaluated easily by Cauchy's residue theorem.

fss = ( UnitStep[a + t] + UnitStep[a - t] - 1)

Plot[fss/.sa,{t,-2,2},PlotRange->{0,1.1`},PlotStyle->Thick,PlotLabel->"f(t) = -1 + UnitStep[1-t] + UnitStep[1 + t]\n",AxesLabel->{"t","f(t)"}, ImageSize ->  250]

fs = FourierCosTransform[fss,t,ω]

InverseFourierTransform[fs,ω,t]

Plot[%/.sa,{t,-2,2},PlotRange->{0,1.1},PlotStyle->Thick,AxesLabel->{"t","f(t)"},ImageSize -> 250];

Gives the same picture as above.

fi = InverseFourierCosTransform[fs, ω, t]

Simplify[fi,{a > 0 && Element[t,Reals]}]

Plot[Chop[fi/.sa],{t,-2,2}];

Gives the same picture as above.

fu = -t UnitStep[-a+t]+ t UnitStep[a+t]

Plot[fu/.sa,{t,-2,2},PlotRange->All,AxesLabel->{"t","fu(t)"},PlotStyle->Thick,ImageSize -> 250]

fut = FourierSinTransform[fu,t,ω]

Plot[fut/.sa,{ω,-15,15},AxesLabel->{"ω","Fu(ω)"}, PlotStyle -> Thick, ImageSize -> 300]

10.6   Exercises

10.1.   Calculate the following limits (obligatory  are 1)  to 3) ):
	1)   [sin(x) - x  cos(x)]/ xn   	for   x -> 0,   	n = 1,2,3,4;
	2)    ln(x) /(1 - x) 	       	for   x  -> 1;
	3)   [ √(x2 - 3)   - x] xn		for   x  ->  ∞, 	n = 0, 1;
	4)   Jn(x)/xn			for   x  ->  0,	n = 1,2,  n ∈ IR+ ;
	5)   Yn(x) xn			for   x  ->  0,	n = 1,2,  n ∈ IR+ ;
	Jn(x)  =   BesselJ[n,x] 	Besselfunction of  first kind of order  n;
	Yn(x)  =  BesselY[n,x] 	Besselfunction of second kind of order  n.

10.2.	Expand the following functions into Taylor's or Laurent's series around x = 0:
 	1)  sin2(x),	2)  sin(√x), 	3)  sin-2(x),	4)   e-x2 ,	5)  ctg3(x),	5)  sin(√(a x  + b)).

10.3.	Calculate the following residues ( 2)  is obligatory) :
      	at   x = 0: 		1)  e-x2/x2	2) e-i4x/x3 	3) Jn(x)/xn+1,  n ∈ IN ;
      	at   x = 2π:		4)  (x2 + 3 x - 1)/sin2x

10.4. 	Do the integrals given below analytically; check the result by differentiating it and by 
	numeric integration ( 2)  is obligatory) :
       	1)  ∫ dx  (3 x   + 1)/[(x + 1)2 (x - 2)], 	    2)  ∫  dx  sin(5 x) cos3(x),
       	3)  ∫  dx  ∫ dy  x y/r2,   r = √(x2 + y2 + z2),    4)  ∫  dx  ∫ dy  x y/r  ;

10.5.   Compute for the octant ( x  ≥ 0,  y ≥ 0,  z ≥ 0)  of the ellipsoid 

			(x/a)2  +  (y/b)2   +  (z/c)2  =  1
		
       	the tensor of  the moment of inertia w.r.t. the following points:
       	1)  x = y = 0,   2)  the center of gravity,    3) x = a/2, y = b/3, z = 4c/9.
       	Compute the eigenvalues and eigenvectors of these tensors  for  
       	4)  a = b, 	      5)  a = 2, b = 5,  c = 4.

10.6   Approximate the sine in the intervall (0, π) by a 3 rd degree polynomial. The coefficients should be determined by the 
          values of the sine at the  points (0, π/2, π) and by the condition that the polynomial should have a horizontal tangent 
          at  π/2.  Plot these two curves. Compare the area between this polynomial and the x-axis with the area under the sine
         curve.

10.7.   The basis, a,  and the length of the arc, b,  of the segment of a circle are given.  Find an approximate analytic 
	expression for the central angle  α   (0 ≤  α  <  180°)  and the height, h, of the segment as functions of  a  and  
	b for  0  ≤  a/b  ≤ 1.  Compare the approximate analytic results to  accurate numeric results in tables and graphs.
       	Hint: Half of the central angle is determined by a transcendental equation,  for which an approximate analytic result is
       	 obtained by one Newton iteration.  The height can be calculated with this angle.

10.8.    Calculate the following integrals by expanding the integrands around  t = 0 and integrating the resulting 
	series (10 terms)  term by  term. Check the accuracy of this approximate result with that obtained  by 
	numeric integration. 
        	1)	   ∫ 0z	dt/	(1 - t4)1/2 ,	0 ≤ z ≤ 0.8 .
        	2)	     ∫ 0z 	dt  t-1/2  (t - 1/2) -1/2 (1 - t + t2/2)-1/2,  	0 ≤ z ≤ 0.2.

10.9+	Evaluate the integral    ∫01 dx  x20  ex     		 in   3   ways:
	1)  N[Integrate], 	2)   NIntegrate[ ]  ,
            3) Series expansion and subsequent term by term integration.
      	Explain the differences in the results and devise all methods such  that each 
      	gives a result correct to 10 decimal places.

10.10  	Investigate the following integral and give its true value or limit.

(∫_(-1)^1) ((x-1)/((x^7)+(x^3)+1))\[DifferentialD]x

10.11  	Find all zeros of the transcendental equation f(z) =  1/2 z  ez  - 1 = 0 contained 
	within the square 50 {1+i,-1+i,-1-i,-1-i}.  Show that you have found all zeros.
	Hint: The large range of the square renders an accurate plot of |f(z)| impractical.
	It is more advantageous to use the theorem: ∫C dz f'(z)/f(z)/(2π I) = N - P, where   N (P)
	 is the number of zeros (poles) located within the counture  C.  The value of 	the 
	 integral may be found by numeric integration.

10.12	Evaluate the following integral analytically and numerically.

(∫_1^2)dx   (∫_1^(x^2))dy    ( (x^2) + (y^2))

10.13	Find  a  method  to  systematically  replace  the  limit

	       (f[y]-f[x])/(y-x) /. y->x

	by   f'[x],   no  matter  what  the  function   f   is.

10.14   Define a function which calculates the Wronskian of  n  functions. Apply it to 
	{sin x, sin 2x, sin 3x} and find the simplest expression for the result.

10.15  Compute the indefinite integral:     ∫|x|   dx .

10.16	Calculate the Laplace transform of the function  f[t], which is zero outside the 
	interval [ 0 < a, b]  and a triangle with the top ((a/2)+(b/2),1) within this intervall.

10.17	Laplace transform: Find the images of the following functions:
	1)  (t^a)(e^(b t)),	2)  (1 - (e^(-t)))/t	,	3) ln t	,	4)  (e^( -(t^2)/4)),	
	5)   cos(x (Sqrt[t]))/(Sqrt[t]) ,	6)   sin(x (Sqrt[t])) ,    7)  ch(x (Sqrt[t]))/(Sqrt[t]) ,	8)   sh(x (Sqrt[t]))	,	
	9)  (e^( -(x^2)/4t))/(Sqrt[t]) ,	10)  (e^( -(x^2)/4t))/(Sqrt[(t^3)]).

10.18	Laplace transform: Find the preimages (= Urbilder) of the following functions:
	1) (s^n)/((s^3) + (ω^3) ),   n = 0, 1, 2;		2)  (s^n)/((s^4) + 4 (ω^4) ),   n = 0, 1, 2, 3;		
	3)  (s^n)/((s^4) -  (ω^4) ),   n = 0, 1, 2, 3; 	4)  Exp[(s^2)],		5)  Exp[- a (Sqrt[s])]/s  .

10.19	The two branches of a parallel circuit consist of 1) a coil (Ohmic resistance R, 
	inductivity L)
	2) of a condensor (capacity C) preceeded by a small resistance r. 
	A voltage step of magnitude V0  is applied to the circuit. Compute and plot 
	the total current and that in each branch.

10.20	Fourier transform: Perform the Fourier transform for the following function:
					cos(ω0 t).

10.21	Find den following limit:  li(Subscript[m, n →∞])(-1)n (({{-1/2}, {n}}))(Sqrt[π n]) .

	Hint:   (((-1))^n)(({{-1/2}, {n}})) =  (((-1/2) (-3/2)...(-(2n - 1)/2))/(n!)) (((-1))^n) = 	(((1/2) (3/2)...(n - 1/2))/(n!))